tidysimple.xqm

xquery version "3.1";

(:~
 : This modules handles the conversion of the Fontante-TEI/XML into TEI simplePrint
 : for the edited text. The resulting TEI simplePrint is the basis for the "Editerter
 : Text" (edited text) view on the website and the book. It represents the latest
 : layer of text.
 :
 : @author Michelle Rodzis
 : @version 0.1
 : @since TODO
 :)

module namespace tidySimple ="http://fontane-nb.dariah.eu/tidysimple";


declare namespace tei="http://www.tei-c.org/ns/1.0";
declare namespace test="http://exist-db.org/xquery/xqsuite";

import module namespace config="http://textgrid.de/ns/SADE/config" at "../../config/config.xqm";
import module namespace console="http://exist-db.org/xquery/console";
import module namespace simpleHelpers="http://fontane-nb.dariah.eu/teisimplehelpers" at "teisimplehelpers.xqm";


declare variable $tidySimple:valid-hands :=
    for $res in collection("/db/sade-projects/textgrid/data/xml/data")
    return
        $res//tei:handNote[@script = "contemporary"]/@xml:id/string();


declare function tidySimple:main($tei as node()*) as xs:string* {
    let $text := $tei//tei:text
    let $tidied-text := tidySimple:tidy($text)
    let $final-tei:=
        <TEI xmlns="http://www.tei-c.org/ns/1.0">
            {$tei//tei:teiHeader}
            {$tidied-text}
        </TEI>

    return xmldb:store("/db/apps/SADE/resources/xml/", "tei-simple.xml", $final-tei)
};


declare function tidySimple:tidy($nodes as node()*) as node()* {
    for $node in $nodes return
        typeswitch ($node)
        case text() return
            $node
        case element(tei:handShift) return
            if(simpleHelpers:is-hand-valid($tidySimple:valid-hands, $node)) then
                tidySimple:clear-handshift($node)
            else
                ()
        default return
            if(simpleHelpers:belongs-to-valid-hand($tidySimple:valid-hands, $node)) then
                tidySimple:copy-second-stage-element($node)
            else
                ()
};


declare function tidySimple:copy-second-stage-element($node as node())
as node() {
    element {QName("http://www.tei-c.org/ns/1.0", $node/name())}{
        $node/@*,
        tidySimple:tidy($node/node())
    }
};


declare function tidySimple:clear-handshift($node as element(tei:handShift))
as element(tei:handShift) {
    element tei:handShift {
        if($node/@new = "") then
            ()
        else
            $node/@new,
        if($node/@script = "") then
            ()
        else
            $node/@script,
        if($node/@medium = "") then
            ()
        else
            $node/@medium
    }
};