build.gradle

// Apply the java-library plugin to add support for Java Library
apply plugin: 'eclipse'
apply plugin: 'java'
apply plugin: 'checkstyle'
apply plugin: 'findbugs'
apply plugin: 'maven'
apply plugin: "com.github.psxpaul.execfork"
apply plugin: 'jacoco'

buildscript {
  repositories {
    maven {
      url "https://plugins.gradle.org/m2/"
    }
  }
  dependencies {
    classpath "gradle.plugin.com.github.psxpaul:gradle-execfork-plugin:0.1.8"
  }
}

sourceSets {
  startMartServer {
    resources {
      srcDir 'src/test/resources'
    }
  }
}


// In this section you declare where to find the dependencies of your project
repositories {
    // Use jcenter for resolving your dependencies.
    // You can declare any Maven/Ivy/file repository here.
    //mavenLocal()
    mavenCentral()
    jcenter()
    maven {
          url "https://nexus.informatik.uni-goettingen.de/content/repositories/thirdparty/"
    }
    maven {
          url "https://nexus.informatik.uni-goettingen.de/content/repositories/rwm/"
    }
    
    flatDir {
        dirs 'lib'
    }
}

dependencies {
	//Nexus
	compile "org.eclipse.uml2:org.eclipse.uml2.uml:4.1.2"
	//runtime?
	compile "org.eclipse.uml2:org.eclipse.uml2.types:1.1.0"
	compile "org.eclipse.uml2:org.eclipse.uml2.common:1.8.2"
	compile group: 'org.eclipse.ocl', name: 'pivot', version: '1.3.0'
	//occiware
	compile group: 'org.eclipse.cmf.occi', name: 'core', version: '1.0.0'
	compile group: 'org.eclipse.cmf.occi', name: 'infrastructure', version: '1.0.0'
	compile group: 'org.eclipse.cmf.occi', name: 'crtp', version: '1.0.0'
	
	//own
	compile group: 'de.ugoe.cs.rwm.pog', name: 'model', version: '1.0.0'
	//compile group: 'de.ugoe.cs.rwm.pcg', name: 'model', version: '1.0.0'
	compile group: 'de.ugoe.cs.rwm', name: 'tocci', version: '1.0.0'
	compile group: 'de.ugoe.cs.rwm', name: 'cocci', version: '1.0.0'
	compile group: 'de.ugoe.cs.rwm', name: 'docci', version: '1.0.0', changing: true
	compile group: 'de.ugoe.cs.rwm.wocci', name: 'model', version: '1.0.0'
	//modmacao
	compile group: 'org.modmacao', name: 'core', version: '1.0.0'
	compile group: 'org.modmacao', name: 'placement', version: '1.0.0'
	compile group: 'org.modmacao.occi', name: 'platform', version: '1.0.0'
	compile group: 'org.modmacao.openstack', name: 'runtime', version: '1.0.0'
	compile group: 'org.modmacao.openstack.swe', name: 'runtime', version: '1.0.0'
	compile group: 'org.modmacao', name: 'ansible', version:'1.0.0'
	
	//maven
	compile group: 'org.eclipse.epsilon', name: 'epsilon-core', version: '1.4.0'
	compile group: 'org.eclipse.epsilon', name: 'epsilon-emf', version: '1.4.0'
	compile group: 'log4j', name: 'log4j', version: '1.2.17'
	compile group: 'com.google.guava', name: 'guava', version: '25.1-jre'
	compile group: 'org.apache.logging.log4j', name: 'log4j-slf4j-impl', version: '2.11.0'
	compile "org.eclipse.core:org.eclipse.core.runtime:3.7.0"
	compile group: 'com.jcraft', name: 'jsch', version: '0.1.54'
	compile group: 'org.json', name: 'json', version: '20180130'
	compile group: 'commons-codec', name: 'commons-codec', version: '1.9'

	
	testCompile group: 'junit', name: 'junit', version: '4.12'
    //testImplementation 'junit:junit:4.12'
}

configurations.all {
    // Check for updates every build
    resolutionStrategy.cacheChangingModulesFor 0, 'seconds'
}

javadoc {
    source = sourceSets.main.allJava
    classpath = configurations.compile
    failOnError = true
}
test {
    exclude 'de/ugoe/cs/rwm/docci/live/**'
    testLogging.showStandardStreams = true
        testLogging {
        exceptionFormat = 'full'
    }
}
tasks.test.dependsOn("startMartServer")
test.finalizedBy jacocoTestReport

jacoco {
    toolVersion = "0.8.1"
}

jacocoTestReport {
    reports {
        xml.enabled false
        csv.enabled false
        html.destination file("${buildDir}/reports/jacoco")
    }
}

findbugs {
    sourceSets = [sourceSets.main]
    ignoreFailures = false
}

checkstyle {
    toolVersion = "8.7"
    sourceSets = [sourceSets.main]
}

checkstyleMain {
    ignoreFailures = true
}

tasks.withType(FindBugs) {
    reports {
        xml.enabled false
        html.enabled true
    }
} 
 
task startMartServer(type: com.github.psxpaul.task.JavaExecFork) {
    classpath = files("src/test/resources/org.occiware.mart.jetty.jar")
    main = 'org.occiware.mart.jetty.MartServer'
    waitForPort = 8080
    stopAfter = test
}


uploadArchives {
    repositories {
       mavenDeployer {
             repository(url: "https://nexus.informatik.uni-goettingen.de/content/repositories/rwm/") {
             authentication(userName: System.getenv('NEXUSUSER'), password: System.getenv('NEXUSPASSWORD'))
            }
            pom.version = "1.0.0"
             pom.artifactId = "mocci"
             pom.groupId = "de.ugoe.cs.rwm"
       }
    }
}